home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Magnum One
/
Magnum One (Mid-American Digital) (Disc Manufacturing).iso
/
d7
/
faxdor14.arc
/
FAXDV.DOC
< prev
next >
Wrap
Text File
|
1991-04-28
|
4KB
|
132 lines
┌─────────────────────┐
│ From: JON ANDERSON │
────────────────────────┤ ├───────────────────────────
│ Date: 04-10-91 │ Used by Permission.
└─────────────────────┘
Now, the fax tsr thing: Here's a well-documented bat file which uses
bitfax v3.0's TSR form , WAIT.com, and Chuck Eglinton's REMCTL58.zip
to do neat thing:
Batch file follows:
@echo off
goto start
REM ***************** Documentation *******************************
REM
REM ***Purpose: Allow use of FAX card, modem, &/or answering maching
REM on a single line, without any switching-device
REM
REM ***Requires: 1) Charles Eglinton's excellent shareware utility
REM called REMOTE CONTROL (latest is REMCTL58.ZIP)
REM 2) Todd Miller's great DOS utility: WAIT.com
REM available as WAITBAT.ZIP
REM 3) DesqView
REM 4) FAX card with TSR-type software, eg: BitFAX v3.0
REM Also useful but not required:
REM 5) David G. Thomas' TAME*.ZIP, a DesqView utility to
REM enhance performance
REM
REM ***Why:
REM
REM Why want 2 separate 1-ring calls to activate FAX? Because having
REM a 1-call requirement obligates the FAX to wait the time defined
REM in the WAIT.com switch line...anyone calling voice will get FAX!
REM So, having a requirement of 2 means one can reset the sequence
REM merely by calling again and ringing a few rings!
REM Also, its unlikely that an unknowing outside party would hangup
REM twice with 1-ring each time.
REM
REM ** How to setup:
REM Just read thru this bat file and make any directory/drive
REM changes to be consistent with your own system. My own
REM approach, for clarity, is to include all drive/directory
REM changes to be written here, even ifnec for the logic
REM of the batch file... this makes things clear, and, as a
REM habit, lets one move steps around within a bat file with
REM less chance for the file 'losing its way' on execution.
REM
REM Setup DV's window : ans. 'Y' to "Close on Exit? ".
REM DV's window must be setup for communications, i.e, it can NOT
REM be allowed to swap out!
REM
REM * By Jon Anderson, Boston Gas BBS
REM 617-235-6303 * USR DS * 24hrs/day * Anes/Med/Science/Engineering
REM
REM **************************************************************
REM
REM You're free, of course, to edit-out all REM'd lines, which are
REM ignored by DOS.
REM
REM ****************** end of documentation ***********************
:start
c:\dv\dvansi
e:
c:\tame\tame-res
:TOP
REM remove any fax tsr from any earlier event:
cd\bitfax
RMV_RECV
REM this makes an errorlevel dep. on how many rings before hangup:
:cycle
cd\remctl58
RC 3 ATS0=0
IF ERRORLEVEL 3 GOTO 3
IF ERRORLEVEL 2 GOTO 2
IF ERRORLEVEL 1 GOTO HALFWAY
IF ERRORLEVEL 0 GOTO ABORT
GOTO TOP
:HALFWAY
REM The wait.com used here will show the errorlevel made by RC.com:
wait 00:00:05
cd\remctl58
REM Gets here ONLY if it was the 2nd 'single ring'.. Anything other than
REM a single prev. ring goes to TOP or ABORT (& same via :2 & :3)
RC 3 ATS0=0
IF ERRORLEVEL==3 GOTO 3
IF ERRORLEVEL 2 GOTO 2
IF ERRORLEVEL 1 GOTO 1
IF ERRORLEVEL 0 GOTO ABORT
GOTO TOP
:1
REM Now here 'cause it was the 2nd single ring...
cd\bitfax
recvfax 3
REM must keep 1 min. here, as recvfax is resident,will keep control
REM as long as fax is comming in ??
c:\wait 00:05:00
if errorlevel 1 goto end
GOTO TOP
:2
REM Put anything you want done on 2 ring hangups here
GOTO TOP
:3
REM Put anything you want done on 3 ring hangups here
GOTO TOP
:ABORT
:end
REM Let's see what TAME did, by the way...:
c:\tame\tame /status
REM and change prompt in case you CTRL-C out of the bat file to
REM keep the window open:
REM (and change prompt to be more useful...)
echo *
echo Hit CTRL-C to keep window open, but NO FAX's CAN BE REC'D!...
echo *
wait 00:00:10
if errorlevel 1 goto stay
exit
:stay
set prompt=-$p-$g
-----
I'm sure Jon spent a fair amount of time creating the wondeful Batch File
and I'd like to pass on my gratitude to him, for allowing the rest of us
to take advantage of his creative imagination!
-----